git.aero2k.de Git - tmp/jakarta-migration.git/blob

   1 grammar StructuredDate;
   2
   3 /*
   4  * This is a grammar for ANTLR 4 (http://www.antlr.org/).
   5  *
   6  */
   7
   8 /*
   9  * Parser rules
  10  */
  11
  12 oneDisplayDate:        displayDate ( DOT | QUESTION )? EOF ;
  13
  14 displayDate:           uncertainDate
  15 |                      certainDate
  16 |                      beforeOrAfterDate
  17 |                      unknownDate
  18 |                      uncalibratedDate
  19 ;
  20
  21 uncertainDate:         CIRCA certainDate ;
  22
  23 certainDate:           hyphenatedRange
  24 |                      singleInterval
  25 ;
  26
  27 beforeOrAfterDate:     ( BEFORE | AFTER ) singleInterval ;
  28
  29 uncalibratedDate:      numYear PLUSMINUS num YEARSSTRING? BP ;
  30
  31 hyphenatedRange:       singleInterval ( HYPHEN | DASH ) singleInterval
  32 |                      nthCenturyRange
  33 |                      monthInYearRange
  34 |                      quarterInYearRange
  35 |                      strDayInMonthRange
  36 |                      numDayInMonthRange
  37 ;
  38
  39 singleInterval:        yearSpanningWinter
  40 |                      partialYear
  41 |                      quarterYear
  42 |                      halfYear
  43 |                      millennium
  44 |                      partialCentury
  45 |                      quarterCentury
  46 |                      halfCentury
  47 |                      century
  48 |                      partialDecade
  49 |                      decade
  50 |                      year
  51 |                      month
  52 |                      date
  53 ;
  54
  55 quarterInYearRange:    nthQuarterInYearRange
  56 |                      strSeasonInYearRange
  57 ;
  58
  59 date:                  numDate
  60 |                      strDate
  61 |                      invStrDate
  62 |                      dayFirstDate
  63 |                      dayOrYearFirstDate
  64 |                      invStrDateEraLastDate
  65 ;
  66
  67 month:                 monthYear
  68 |                      invMonthYear
  69 ;
  70
  71 yearSpanningWinter:    WINTER COMMA? numYear SLASH numYear era? ;
  72
  73 partialYear:           partOf numYear era? ;
  74
  75 quarterYear:           seasonYear
  76 |                      invSeasonYear
  77 |                      nthQuarterYear
  78 ;
  79
  80 halfYear:              nthHalf numYear era? ;
  81
  82 year:                  numYear era? ;
  83
  84 partialDecade:         partOf numDecade era? ;
  85
  86 decade:                numDecade era? ;
  87
  88 partialCentury:        partOf ( strCentury | numCentury ) era? ;
  89
  90 quarterCentury:        nthQuarter ( strCentury | numCentury ) era? ;
  91
  92 halfCentury:           nthHalf ( strCentury | numCentury ) era? ;
  93
  94 century:               ( strCentury | numCentury ) era? ;
  95
  96 millennium:            nth MILLENNIUM era? ;
  97
  98 strDate:               strMonth ( numDayOfMonth | nth ) COMMA? numYear era?;
  99 invStrDate:            era num COMMA? strMonth num
 100 |                      era? num COMMA strMonth num ;
 101 dayFirstDate:          num strMonth COMMA? num era
 102 |                      num strMonth COMMA num era?
 103 |                      nth strMonth COMMA? num era? ;
 104 dayOrYearFirstDate:    num strMonth num ;
 105 invStrDateEraLastDate: num COMMA strMonth num era? ;
 106 strDayInMonthRange:    strMonth numDayOfMonth ( HYPHEN | DASH ) numDayOfMonth COMMA? numYear era? ;
 107 monthInYearRange:      strMonth ( HYPHEN | DASH ) strMonth COMMA? numYear era? ;
 108 nthQuarterInYearRange: nthQuarter ( HYPHEN | DASH ) nthQuarter COMMA? numYear era? ;
 109 strSeasonInYearRange:  strSeason ( HYPHEN | DASH ) strSeason COMMA? numYear era? ;
 110 numDayInMonthRange:    numMonth SLASH num ( HYPHEN | DASH ) num SLASH numYear era? ;
 111 numDate:               num SLASH ( num | romanNum ) SLASH num era?
 112 |                      num HYPHEN ( num | romanNum ) HYPHEN num era? ;
 113 monthYear:             strMonth COMMA? numYear era? ;
 114 invMonthYear:          era? numYear COMMA? strMonth ;
 115 seasonYear:            strSeason COMMA? numYear era? ;
 116 invSeasonYear:         era? numYear COMMA? strSeason ;
 117 nthQuarterYear:        nthQuarter numYear era? ;
 118 nthQuarter:            ( nth | LAST ) QUARTER ;
 119 nthHalf:               ( nth | LAST ) HALF ;
 120 numDecade:             TENS ;
 121 strCentury:            nth CENTURY ;
 122 numCentury:            HUNDREDS ;
 123 nthCenturyRange:       allOrPartOf nth ( HYPHEN | DASH ) allOrPartOf nth CENTURY era? ;
 124 strSeason:             SPRING | SUMMER | FALL | WINTER ;
 125 allOrPartOf:           partOf | ;
 126 partOf:                EARLY | MIDDLE | LATE ;
 127 nth:                   NTHSTR | FIRST | SECOND | THIRD | FOURTH ;
 128 strMonth:              MONTH | SHORTMONTH DOT? ;
 129 era:                   BC | AD ;
 130 numYear:               NUMBER ;
 131 numMonth:              NUMBER ;
 132 numDayOfMonth:         NUMBER ;
 133 num:                   NUMBER ;
 134 unknownDate:           UNKNOWN ;
 135 romanNum:              ROMANNUMBER ;
 136
 137 /*
 138  * Lexer rules
 139  */
 140 WS:             [ \t\r\n]+ -> skip;
 141 PLUSMINUS:      '±' | '+/-' ;
 142 CIRCA:          ('c' | 'ca') DOT? | 'circa' ;
 143 SPRING:         'spring' | 'spr' ;
 144 SUMMER:         'summer' | 'sum' ;
 145 WINTER:         'winter' | 'win' ;
 146 FALL:           'fall' | 'autumn' | 'fal' | 'aut' ;
 147 EARLY:          'early' ;
 148 MIDDLE:         'middle' | 'mid' ( HYPHEN | DOT )?;
 149 LATE:           'late' ;
 150 BEFORE:         'before' | 'pre' HYPHEN? ;
 151 AFTER:          'after' | 'post' HYPHEN? ;
 152 FIRST:          'first' ;
 153 SECOND:         'second' ;
 154 THIRD:          'third' ;
 155 FOURTH:         'fourth' ;
 156 LAST:           'last' ;
 157 QUARTER:        'quarter' ;
 158 HALF:           'half' ;
 159 CENTURY:        'century' ;
 160 MILLENNIUM:     'millennium' ;
 161 MONTH:          'january' | 'february' | 'march' | 'april' | 'may' | 'june' | 'july' | 'august' | 'september' | 'october' | 'november' | 'december' ;
 162 SHORTMONTH:     'jan' | 'feb' | 'mar' | 'apr' | 'jun' | 'jul' | 'aug' | 'sep' | 'sept' | 'oct' | 'nov' | 'dec' ;
 163 BC:             'bc' | 'bce' |  'b.c.' | 'b.c.e.' ;
 164 AD:             'ad' | 'a.d.' | 'ce' | 'c.e.' ;
 165 BP:             'bp' | 'b.p.' | 'b.p' ;
 166 NTHSTR:         [0-9]*? ([0456789] 'th' | '1st' | '2nd' | '3rd' | '11th' | '12th' | '13th') ;
 167 HUNDREDS:       [0-9]*? '00' '\''? 's';
 168 TENS:           [0-9]*? '0' '\''? 's';
 169 NUMBER:         ([0-9,]+)*[0-9] ;
 170 ROMANNUMBER:    [ivx]+ ;
 171 COMMA:          ',' ;
 172 HYPHEN:         '-' ;
 173 DASH:           [—–] ; /* EM DASH, EN DASH */
 174 SLASH:          '/' ;
 175 DOT:            '.' ;
 176 QUESTION:       '?' ;
 177 OTHER:          . ;
 178 UNKNOWN:        'unknown' ;
 179 YEARSSTRING:    'years' | 'year' ;
 180 STRING:         [a-z]+ ;