git.aero2k.de Git - tmp/jakarta-migration.git/blob

   1 grammar StructuredDate;
   2
   3 /*
   4  * This is a grammar for ANTLR 4 (http://www.antlr.org/).
   5  *
   6  */
   7
   8 /*
   9  * Parser rules
  10  */
  11
  12 oneDisplayDate:        displayDate ( DOT | QUESTION )? EOF ;
  13
  14 displayDate:           uncertainDate
  15 |                      certainDate
  16 /* TODO: Need to decide what "before" and "after" actually mean
  17 |                      beforeOrAfterDate
  18 */
  19 ;
  20
  21 uncertainDate:         CIRCA certainDate ;
  22
  23 certainDate:           hyphenatedRange
  24 |                      singleInterval
  25 ;
  26
  27 beforeOrAfterDate:     ( BEFORE | AFTER ) singleInterval ;
  28
  29 hyphenatedRange:       singleInterval ( HYPHEN | DASH ) singleInterval
  30 |                      nthCenturyRange
  31 |                      monthInYearRange
  32 |                      quarterInYearRange
  33 |                      strDayInMonthRange
  34 |                      numDayInMonthRange
  35 ;
  36
  37 singleInterval:        yearSpanningWinter
  38 |                      partialYear
  39 |                      quarterYear
  40 |                      halfYear
  41 |                      millennium
  42 |                      partialCentury
  43 |                      quarterCentury
  44 |                      halfCentury
  45 |                      century
  46 |                      partialDecade
  47 |                      decade
  48 |                      year
  49 |                      month
  50 |                      date
  51 ;
  52
  53 quarterInYearRange:    nthQuarterInYearRange
  54 |                      strSeasonInYearRange
  55 ;
  56
  57 date:                  numDate
  58 |                      strDate
  59 |                      invStrDate
  60 |                      dayFirstDate
  61 |                      dayOrYearFirstDate
  62 |                      invStrDateEraLastDate
  63 ;
  64
  65 month:                 monthYear
  66 |                      invMonthYear
  67 ;
  68
  69 yearSpanningWinter:    WINTER COMMA? numYear SLASH numYear era? ;
  70
  71 partialYear:           partOf numYear era? ;
  72
  73 quarterYear:           seasonYear
  74 |                      invSeasonYear
  75 |                      nthQuarterYear
  76 ;
  77
  78 halfYear:              nthHalf numYear era? ;
  79
  80 year:                  numYear era? ;
  81
  82 partialDecade:         partOf numDecade era? ;
  83
  84 decade:                numDecade era? ;
  85
  86 partialCentury:        partOf ( strCentury | numCentury ) era? ;
  87
  88 quarterCentury:        nthQuarter ( strCentury | numCentury ) era? ;
  89
  90 halfCentury:           nthHalf ( strCentury | numCentury ) era? ;
  91
  92 century:               ( strCentury | numCentury ) era? ;
  93
  94 millennium:            nth MILLENNIUM era? ;
  95
  96 strDate:               strMonth ( numDayOfMonth | nth ) COMMA? numYear era?;
  97 invStrDate:            era num COMMA? strMonth num
  98 |                      era? num COMMA strMonth num ;
  99 dayFirstDate:          num strMonth COMMA? num era
 100 |                      num strMonth COMMA num era?
 101 |                      nth strMonth COMMA? num era? ;
 102 dayOrYearFirstDate:    num strMonth num ;
 103 invStrDateEraLastDate: num COMMA strMonth num era? ;
 104 strDayInMonthRange:    strMonth numDayOfMonth ( HYPHEN | DASH ) numDayOfMonth COMMA? numYear era? ;
 105 monthInYearRange:      strMonth ( HYPHEN | DASH ) strMonth COMMA? numYear era? ;
 106 nthQuarterInYearRange: nthQuarter ( HYPHEN | DASH ) nthQuarter COMMA? numYear era? ;
 107 strSeasonInYearRange:  strSeason ( HYPHEN | DASH ) strSeason COMMA? numYear era? ;
 108 numDayInMonthRange:    numMonth SLASH numDayOfMonth ( HYPHEN | DASH ) numDayOfMonth SLASH numYear era? ;
 109 numDate:               num SLASH num SLASH num era?
 110 |                      num HYPHEN num HYPHEN num era? ;
 111 monthYear:             strMonth COMMA? numYear era? ;
 112 invMonthYear:          era? numYear COMMA? strMonth ;
 113 seasonYear:            strSeason COMMA? numYear era? ;
 114 invSeasonYear:         era? numYear COMMA? strSeason ;
 115 nthQuarterYear:        nthQuarter numYear era? ;
 116 nthQuarter:            ( nth | LAST ) QUARTER ;
 117 nthHalf:               ( nth | LAST ) HALF ;
 118 numDecade:             TENS ;
 119 strCentury:            nth CENTURY ;
 120 numCentury:            HUNDREDS ;
 121 nthCenturyRange:       allOrPartOf nth ( HYPHEN | DASH ) allOrPartOf nth CENTURY era? ;
 122 strSeason:             SPRING | SUMMER | FALL | WINTER ;
 123 allOrPartOf:           partOf | ;
 124 partOf:                EARLY | MIDDLE | LATE ;
 125 nth:                   NTHSTR | FIRST | SECOND | THIRD | FOURTH ;
 126 strMonth:              MONTH | SHORTMONTH DOT? ;
 127 era:                   BC | AD ;
 128 numYear:               NUMBER ;
 129 numMonth:              NUMBER ;
 130 numDayOfMonth:         NUMBER ;
 131 num:                   NUMBER ;
 132
 133
 134 /*
 135  * Lexer rules
 136  */
 137
 138 WS:             [ \t\r\n]+ -> skip;
 139 CIRCA:          ('c' | 'ca') DOT? | 'circa' ;
 140 SPRING:         'spring' | 'spr' ;
 141 SUMMER:         'summer' | 'sum' ;
 142 WINTER:         'winter' | 'win' ;
 143 FALL:           'fall' | 'autumn' | 'fal' | 'aut' ;
 144 EARLY:          'early' ;
 145 MIDDLE:         'middle' | 'mid' ( HYPHEN | DOT )?;
 146 LATE:           'late' ;
 147 BEFORE:         'before' | 'pre' HYPHEN? ;
 148 AFTER:          'after' | 'post' HYPHEN? ;
 149 FIRST:          'first' ;
 150 SECOND:         'second' ;
 151 THIRD:          'third' ;
 152 FOURTH:         'fourth' ;
 153 LAST:           'last' ;
 154 QUARTER:        'quarter' ;
 155 HALF:           'half' ;
 156 CENTURY:        'century' ;
 157 MILLENNIUM:     'millennium' ;
 158 MONTH:          'january' | 'february' | 'march' | 'april' | 'may' | 'june' | 'july' | 'august' | 'september' | 'october' | 'november' | 'december' ;
 159 SHORTMONTH:     'jan' | 'feb' | 'mar' | 'apr' | 'jun' | 'jul' | 'aug' | 'sep' | 'sept' | 'oct' | 'nov' | 'dec' ;
 160 BC:             'bc' | 'bce' |  'b.c.' | 'b.c.e.' ;
 161 AD:             'ad' | 'a.d.' | 'ce' | 'c.e.';
 162 NTHSTR:         [0-9]*? ([0456789] 'th' | '1st' | '2nd' | '3rd' | '11th' | '12th' | '13th') ;
 163 HUNDREDS:       [0-9]*? '00' '\''? 's';
 164 TENS:           [0-9]*? '0' '\''? 's';
 165 NUMBER:         [0-9]+ ;
 166 COMMA:          ',' ;
 167 HYPHEN:         '-' ;
 168 DASH:           [—–] ; /* EM DASH, EN DASH */
 169 SLASH:          '/' ;
 170 DOT:            '.' ;
 171 QUESTION:       '?' ;
 172 STRING:         [a-z]+ ;
 173 OTHER:          . ;