git.aero2k.de Git - tmp/jakarta-migration.git/blob

   1 grammar StructuredDate;
   2
   3 /*
   4  * This is a grammar for ANTLR 4 (http://www.antlr.org/).
   5  *
   6  */
   7
   8 /*
   9  * Parser rules
  10  */
  11 // unknownDisplayDate:
  12
  13 oneDisplayDate:        displayDate ( DOT | QUESTION )? EOF ;
  14
  15 displayDate:           uncertainDate
  16 |                      certainDate
  17 /* TODO: Need to decide what "before" and "after" actually mean
  18 |                      beforeOrAfterDate
  19 */
  20 |                      beforeOrAfterDate
  21 // |                      unknownDate
  22 ;
  23
  24 uncertainDate:         CIRCA certainDate ;
  25
  26 certainDate:           hyphenatedRange
  27 |                      singleInterval
  28 ;
  29
  30 beforeOrAfterDate:     ( BEFORE | AFTER ) singleInterval ;
  31
  32 hyphenatedRange:       singleInterval ( HYPHEN | DASH ) singleInterval
  33 |                      nthCenturyRange
  34 |                      monthInYearRange
  35 |                      quarterInYearRange
  36 |                      strDayInMonthRange
  37 |                      numDayInMonthRange
  38 ;
  39
  40 singleInterval:        yearSpanningWinter
  41 |                      partialYear
  42 |                      quarterYear
  43 |                      halfYear
  44 |                      millennium
  45 |                      partialCentury
  46 |                      quarterCentury
  47 |                      halfCentury
  48 |                      century
  49 |                      partialDecade
  50 |                      decade
  51 |                      year
  52 |                      month
  53 |                      date
  54 ;
  55
  56 quarterInYearRange:    nthQuarterInYearRange
  57 |                      strSeasonInYearRange
  58 ;
  59
  60 date:                  numDate
  61 |                      strDate
  62 |                      invStrDate
  63 |                      dayFirstDate
  64 |                      dayOrYearFirstDate
  65 |                      invStrDateEraLastDate
  66 ;
  67
  68 month:                 monthYear
  69 |                      invMonthYear
  70 ;
  71
  72 yearSpanningWinter:    WINTER COMMA? numYear SLASH numYear era? ;
  73
  74 partialYear:           partOf numYear era? ;
  75
  76 quarterYear:           seasonYear
  77 |                      invSeasonYear
  78 |                      nthQuarterYear
  79 ;
  80
  81 halfYear:              nthHalf numYear era? ;
  82
  83 year:                  numYear era? ;
  84
  85 partialDecade:         partOf numDecade era? ;
  86
  87 decade:                numDecade era? ;
  88
  89 partialCentury:        partOf ( strCentury | numCentury ) era? ;
  90
  91 quarterCentury:        nthQuarter ( strCentury | numCentury ) era? ;
  92
  93 halfCentury:           nthHalf ( strCentury | numCentury ) era? ;
  94
  95 century:               ( strCentury | numCentury ) era? ;
  96
  97 millennium:            nth MILLENNIUM era? ;
  98
  99 strDate:               strMonth ( numDayOfMonth | nth ) COMMA? numYear era;
 100 invStrDate:            era num COMMA? strMonth num
 101 |                      ( num | nth ) strMonth COMMA? num era ;
 102 strDayInMonthRange:    strMonth numDayOfMonth ( HYPHEN | DASH ) numDayOfMonth COMMA? numYear era ;
 103 monthInYearRange:      strMonth ( HYPHEN | DASH ) strMonth COMMA? numYear era ;
 104 nthQuarterInYearRange: nthQuarter ( HYPHEN | DASH ) nthQuarter COMMA? numYear era ;
 105 strSeasonInYearRange:  strSeason ( HYPHEN | DASH ) strSeason COMMA? numYear era ;
 106 numDayInMonthRange:    numMonth SLASH numDayOfMonth ( HYPHEN | DASH ) numDayOfMonth SLASH numYear era
 107 |                      numMonth SLASH numYear ( HYPHEN | DASH ) numMonth SLASH numYear era ;
 108 numDate:               num SLASH num SLASH num era
 109 |                      num HYPHEN num HYPHEN num era ;
 110 monthYear:             strMonth COMMA? numYear era ;
 111 invMonthYear:          era numYear COMMA? strMonth ;
 112 seasonYear:            strSeason COMMA? numYear era ;
 113 invSeasonYear:         era numYear COMMA? strSeason ;
 114 nthQuarterYear:        nthQuarter numYear era ;
 115 nthQuarter:            ( nth | LAST ) QUARTER ;
 116 nthHalf:               ( nth | LAST ) HALF ;
 117 numDecade:             TENS ;
 118 strCentury:            nth CENTURY ;
 119 numCentury:            HUNDREDS ;
 120 nthCenturyRange:       allOrPartOf nth ( HYPHEN | DASH ) allOrPartOf nth CENTURY era? ;
 121 strSeason:             SPRING | SUMMER | FALL | WINTER ;
 122 allOrPartOf:           partOf | ;
 123 partOf:                EARLY | MIDDLE | LATE ;
 124 nth:                   NTHSTR | FIRST | SECOND | THIRD | FOURTH ;
 125 strMonth:              MONTH | SHORTMONTH DOT? ;
 126 era:                   BC | AD ;
 127 numYear:               NUMBER ;
 128 numMonth:              NUMBER ;
 129 numDayOfMonth:         NUMBER ;
 130 num:                   NUMBER ;
 131 // unknownDate:           UNKNOWN ;
 132
 133 /*
 134  * Lexer rules
 135  */
 136
 137 WS:             [ \t\r\n]+ -> skip;
 138 CIRCA:          ('c' | 'ca') DOT? | 'circa' ;
 139 SPRING:         'spring' | 'spr' ;
 140 SUMMER:         'summer' | 'sum' ;
 141 WINTER:         'winter' | 'win' ;
 142 FALL:           'fall' | 'autumn' | 'fal' | 'aut' ;
 143 EARLY:          'early' ;
 144 MIDDLE:         'middle' | 'mid' ( HYPHEN | DOT )?;
 145 LATE:           'late' ;
 146 BEFORE:         'before' | 'pre' HYPHEN? ;
 147 AFTER:          'after' | 'post' HYPHEN? ;
 148 FIRST:          'first' ;
 149 SECOND:         'second' ;
 150 THIRD:          'third' ;
 151 FOURTH:         'fourth' ;
 152 LAST:           'last' ;
 153 QUARTER:        'quarter' ;
 154 HALF:           'half' ;
 155 CENTURY:        'century' ;
 156 MILLENNIUM:     'millennium' ;
 157 MONTH:          'january' | 'february' | 'march' | 'april' | 'may' | 'june' | 'july' | 'august' | 'september' | 'october' | 'november' | 'december' ;
 158 SHORTMONTH:     'jan' | 'feb' | 'mar' | 'apr' | 'jun' | 'jul' | 'aug' | 'sep' | 'sept' | 'oct' | 'nov' | 'dec' ;
 159 BC:             'bc' | 'bce' |  'b.c.' | 'b.c.e.' ;
 160 AD:             'ad' | 'a.d.' | 'ce' | 'c.e.';
 161 NTHSTR:         [0-9]*? ([0456789] 'th' | '1st' | '2nd' | '3rd' | '11th' | '12th' | '13th') ;
 162 HUNDREDS:       [0-9]*? '00' '\''? 's';
 163 TENS:           [0-9]*? '0' '\''? 's';
 164 NUMBER:         [0-9]+ ;
 165 COMMA:          ',' ;
 166 HYPHEN:         '-' ;
 167 DASH:           [—–] ; /* EM DASH, EN DASH */
 168 SLASH:          '/' ;
 169 DOT:            '.' ;
 170 QUESTION:       '?' ;
 171 STRING:         [a-z]+ ;
 172 OTHER:          . ;
 173 // UNKNOWN:        'unknown';