git.aero2k.de Git - tmp/jakarta-migration.git/blob

   1 grammar StructuredDate;
   2
   3 /*
   4  * This is a grammar for ANTLR 4 (http://www.antlr.org/).
   5  *
   6  */
   7
   8 /*
   9  * Parser rules
  10  */
  11
  12 oneDisplayDate:        displayDate ( DOT | QUESTION )? EOF ;
  13
  14 displayDate:           uncertainDate
  15 |                      certainDate
  16 /* TODO: Need to decide what "before" and "after" actually mean
  17 |                      beforeOrAfterDate
  18 */
  19 ;
  20
  21 uncertainDate:         CIRCA certainDate ;
  22
  23 certainDate:           hyphenatedRange
  24 |                      singleInterval
  25 ;
  26
  27 beforeOrAfterDate:     ( BEFORE | AFTER ) singleInterval ;
  28
  29 hyphenatedRange:       singleInterval ( HYPHEN | DASH ) singleInterval
  30 |                      nthCenturyRange
  31 |                      monthInYearRange
  32 |                      quarterInYearRange
  33 |                      strDayInMonthRange
  34 |                      numDayInMonthRange
  35 ;
  36
  37 singleInterval:        yearSpanningWinter
  38 |                      partialYear
  39 |                      quarterYear
  40 |                      halfYear
  41 |                      millennium
  42 |                      partialCentury
  43 |                      quarterCentury
  44 |                      halfCentury
  45 |                      century
  46 |                      partialDecade
  47 |                      decade
  48 |                      year
  49 |                      month
  50 |                      date
  51 ;
  52
  53 quarterInYearRange:    nthQuarterInYearRange
  54 |                      strSeasonInYearRange
  55 ;
  56
  57 date:                  numDate
  58 |                      strDate
  59 |                      invStrDate
  60 ;
  61
  62 month:                 monthYear
  63 |                      invMonthYear
  64 ;
  65
  66 yearSpanningWinter:    WINTER COMMA? numYear SLASH numYear era ;
  67
  68 partialYear:           partOf numYear era ;
  69
  70 quarterYear:           seasonYear
  71 |                      invSeasonYear
  72 |                      nthQuarterYear
  73 ;
  74
  75 halfYear:              nthHalf numYear era ;
  76
  77 year:                  numYear era ;
  78
  79 partialDecade:         partOf numDecade era ;
  80
  81 decade:                numDecade era ;
  82
  83 partialCentury:        partOf ( strCentury | numCentury ) era ;
  84
  85 quarterCentury:        nthQuarter ( strCentury | numCentury ) era ;
  86
  87 halfCentury:           nthHalf ( strCentury | numCentury ) era ;
  88
  89 century:               ( strCentury | numCentury ) era ;
  90
  91 millennium:            nth MILLENNIUM era ;
  92
  93 strDate:               strMonth ( numDayOfMonth | nth ) COMMA? numYear era;
  94 invStrDate:            era num COMMA? strMonth num
  95 |                      ( num | nth ) strMonth COMMA? num era ;
  96 strDayInMonthRange:    strMonth numDayOfMonth ( HYPHEN | DASH ) numDayOfMonth COMMA? numYear era ;
  97 monthInYearRange:      strMonth ( HYPHEN | DASH ) strMonth COMMA? numYear era ;
  98 nthQuarterInYearRange: nthQuarter ( HYPHEN | DASH ) nthQuarter COMMA? numYear era ;
  99 strSeasonInYearRange:  strSeason ( HYPHEN | DASH ) strSeason COMMA? numYear era ;
 100 numDayInMonthRange:    numMonth SLASH numDayOfMonth ( HYPHEN | DASH ) numDayOfMonth SLASH numYear era ;
 101 numDate:               num SLASH num SLASH num era
 102 |                      num HYPHEN num HYPHEN num era ;
 103 monthYear:             strMonth COMMA? numYear era ;
 104 invMonthYear:          era numYear COMMA? strMonth ;
 105 seasonYear:            strSeason COMMA? numYear era ;
 106 invSeasonYear:         era numYear COMMA? strSeason ;
 107 nthQuarterYear:        nthQuarter numYear era ;
 108 nthQuarter:            ( nth | LAST ) QUARTER ;
 109 nthHalf:               ( nth | LAST ) HALF ;
 110 numDecade:             TENS ;
 111 strCentury:            nth CENTURY ;
 112 numCentury:            HUNDREDS ;
 113 nthCenturyRange:       allOrPartOf nth ( HYPHEN | DASH ) allOrPartOf nth CENTURY era ;
 114 strSeason:             SPRING | SUMMER | FALL | WINTER ;
 115 allOrPartOf:           partOf | ;
 116 partOf:                EARLY | MIDDLE | LATE ;
 117 nth:                   NTHSTR | FIRST | SECOND | THIRD | FOURTH ;
 118 strMonth:              MONTH | SHORTMONTH DOT? ;
 119 era:                   BC | AD | ;
 120 numYear:               NUMBER ;
 121 numMonth:              NUMBER ;
 122 numDayOfMonth:         NUMBER ;
 123 num:                   NUMBER ;
 124
 125
 126 /*
 127  * Lexer rules
 128  */
 129
 130 WS:             [ \t\r\n]+ -> skip;
 131 CIRCA:          ('c' | 'ca') DOT? | 'circa' ;
 132 SPRING:         'spring' | 'spr' ;
 133 SUMMER:         'summer' | 'sum' ;
 134 WINTER:         'winter' | 'win' ;
 135 FALL:           'fall' | 'autumn' | 'fal' | 'aut' ;
 136 EARLY:          'early' ;
 137 MIDDLE:         'middle' | 'mid' ( HYPHEN | DOT )?;
 138 LATE:           'late' ;
 139 BEFORE:         'before' | 'pre' HYPHEN? ;
 140 AFTER:          'after' | 'post' HYPHEN? ;
 141 FIRST:          'first' ;
 142 SECOND:         'second' ;
 143 THIRD:          'third' ;
 144 FOURTH:         'fourth' ;
 145 LAST:           'last' ;
 146 QUARTER:        'quarter' ;
 147 HALF:           'half' ;
 148 CENTURY:        'century' ;
 149 MILLENNIUM:     'millennium' ;
 150 MONTH:          'january' | 'february' | 'march' | 'april' | 'may' | 'june' | 'july' | 'august' | 'september' | 'october' | 'november' | 'december' ;
 151 SHORTMONTH:     'jan' | 'feb' | 'mar' | 'apr' | 'jun' | 'jul' | 'aug' | 'sep' | 'sept' | 'oct' | 'nov' | 'dec' ;
 152 BC:             'bc' | 'bce' |  'b.c.' | 'b.c.e.' ;
 153 AD:             'ad' | 'a.d.' | 'ce' | 'c.e.';
 154 NTHSTR:         [0-9]*? ([0456789] 'th' | '1st' | '2nd' | '3rd' | '11th' | '12th' | '13th') ;
 155 HUNDREDS:       [0-9]*? '00' '\''? 's';
 156 TENS:           [0-9]*? '0' '\''? 's';
 157 NUMBER:         [0-9]+ ;
 158 COMMA:          ',' ;
 159 HYPHEN:         '-' ;
 160 DASH:           [—–] ; /* EM DASH, EN DASH */
 161 SLASH:          '/' ;
 162 DOT:            '.' ;
 163 QUESTION:       '?' ;
 164 STRING:         [a-z]+ ;
 165 OTHER:          . ;